' ****************************************************************
' * File:  gmbdae.bas  -  Ver. 1.1                               *
' * Compiler:  PIC Basic PRO                                     *
' * IDE: MicroCode Studio Plus                                   *
' * Compiler Version: 2.45                                       *
' * Boards: GMM 4620 + GMB HR168                                 *
' *   GRIFO(R)   via Dell'Artigiano 8/6                          *
' *   40016 S. Giorgio di Piano (BO)                             *
' *   Tel. +39 051 892052                   Fax. +39 051 893661  *
' *   http://www.grifo.com                  http://www.grifo.it  *
' * by Graziano Gaiba                              08.02.05      *
' ****************************************************************
'
' This demo uses section CCP1 Mini Module to generate, on CN7,
' a PWM signal with preset frequency and duty cycle programmable
' in percent by console.
' Such signal, connected to an opportune intergrating circuit
' (RC network, operational amplifire with capacitor on feedback, etc.)
' allows to obtain an anlog signal like the one of a D/A.
' Demo execution depends on serial line configuration.
'
' Rel 1.1 - by Graziano Gaiba
' Demo program for low level PWM usage with GMB HR168 driven
' by Mini Module GMM 4620
'
'
' ******************** Compiler definitions **********************
'
DEFINE OSC 10 ' Oscillator frequency 9,8304 MHz
DEFINE HSER_RCSTA 90h  ' Enable EUSART serial receiver
DEFINE HSER_TXSTA 20h  ' Enable EUSART serial transmitter
DEFINE HSER_BAUD 19200 ' Baud Rate
'
' ******************* Constants declaration **********************
'
RTCSLA con $A0
I2C_BUFFER_SIZE con 10
'
' ******************** Variables declaration *********************
'
' Generic variables
i var byte
scelta var byte
di var byte
do var byte
'
' Used by I/O management procedures
port_val var byte  ' Value read or to be written to the I/O
'
' Used by PWM demo management
duty_cycle var word
'
'
'************************** Main Program *******************************
'
main:
    gosub Init_cpu
    ' Turn OFF relays
    port_val = 0
    gosub set_relays
    gosub clrscr
    hserout ["Low level PWM demo Rel 1.1 for GMM 4620 rel 120304 and GMB HR168 rel 110104", 13, 10, 13, 10]
    hserout ["This demo generates a PWM signal at about 10 kHz on pin 6 of CN7.", 13, 10]
    hserout ["To work properly, pin 6 of CN7 must be not connected to relay OUT D2 and", 13, 10]
    hserout ["to RS 485 section so please connect J10 in 1-2 and 4-5.", 13, 10]
    gosub wait_key
    hserout [13, 10, 13, 10]
    ' Prescaler of Timer 2 is 1
    t2con = 0
    ' Pin CCP1 is output
    trisc.2 = 0
    ' Module CCP1 in CCP standard PWM mode
    eccp1con = $0f
    ' About 10 KHz of frequency for PWM signal
    pr2 = $ff
    ' Start timer 2, timer 2 is time base for PWM mode of CCP
    t2con.2 = 1
for_ever:
    hserout ["Duty cycle (UPPERCASE hexadecimal from 0 to 03FF): "]
    hserin [hex4 duty_cycle]
    hserout [hex4 duty_cycle, 13, 10]
    if duty_cycle > $3ff then for_ever
    eccp1con.4 = duty_cycle.0
    eccp1con.5 = duty_cycle.1
    ccpr1l = duty_cycle.lowbyte >> 2
    ccpr1l.6 = duty_cycle.8
    ccpr1l.7 = duty_cycle.9
    
    goto for_ever
end
'
' **************** Procedures definition ******************
'
'
' CPU and signals directions initialization
Init_cpu:
    ADCON1=$0f        ' Imposta come I/O digitale i pin AN0..12
    CMCON=$07         ' Imposta come I/O digitale RA0..4
    ' Optocoupled Inputs of CN1 are:
    ' IN1-1 <-> RA0
    ' IN2-1 <-> RA1
    ' IN3-1 <-> RB0
    ' IN4-1 <-> RB1
    ' IN5-1 <-> RA4
    ' IN6-1 <-> RC0
    ' IN7-1 <-> RC1
    ' IN8-1 <-> RC5
    trisa.0 = 1
    trisa.1 = 1
    trisa.4 = 1
    trisb.0 = 1
    trisb.1 = 1
    trisc.0 = 1
    trisc.1 = 1
    trisc.5 = 1
    ' Optocoupled Inputs of CN2 are:
    ' IN1-2 <-> RD0
    ' IN2-2 <-> RD1
    ' IN3-2 <-> RD2
    ' IN4-2 <-> RD3
    ' IN5-2 <-> RD4
    ' IN6-2 <-> RD5
    ' IN7-2 <-> RD6
    ' IN8-2 <-> RD7
    trisd = $ff
    ' Relay outputs of CN3 are:
    ' OUT A1 <-> RB4
    ' OUT A2 <-> RB5
    ' OUT B1 <-> RB6
    ' OUT B2 <-> RB7
    ' OUT C1 <-> RB3
    ' OUT C2 <-> RB2
    trisb = trisb & $03
    ' Relay outputs of CN4 are:
    ' OUT D1 <-> RA3
    ' OUT D2 <-> RC2 (J10 in position 3-4)
    trisa.3 = 0
    trisc.2 = 0
return
'
'
' Clear screen, sending 25 times CR + LF.
clrscr:
    for i= 0 to 24
      hserout [13, 10]
    next i
return
'
'
' Asks for a key press
wait_key:
    hserout ["Press a key..."]
wait_key_loop:
    hserin 1, wait_key_loop, [i]
return
'
'
' Procedure to set the status of the relays on connectors CN3 and CN4.
' According to the bits of port_val, each relay is turned ON
' (contact closed) or OFF (contact open).
' Bits of port_val have this meanging:
' -- CN3
' port_val.0 drives relay OUT A1
' port_val.1 drives relay OUT A2
' port_val.2 drives relay OUT B1
' port_val.3 drives relay OUT B2
' port_val.4 drives relay OUT C1
' port_val.5 drives relay OUT C2
' -- CN4
' port_val.6 drives relay OUT D1
' port_val.7 drives relay OUT D2
'
' Each bit has the following meaning:
'   bit              Meaning
'    0    Relay turned OFF (contact open)
'    1    Relay turned ON (contact closed)
set_relays:
    ' Relays are driven in complemented logic, so port_val must be
    ' complemented too
    port_val = port_val ^ $ff
    portb.4 = port_val.0
    portb.5 = port_val.1
    portb.6 = port_val.2
    portb.7 = port_val.3
    portb.3 = port_val.4
    portb.2 = port_val.5
    
    porta.3 = port_val.6
    
    portc.2 = port_val.7
return