' ****************************************************************
' * File:  k51ppo.bas  -  Ver. 1.1                               *
' * Compilatore:  PIC Basic PRO                                  *
' * IDE: MicroCode Studio Plus                                   *
' * Versione Compilatore: 2.45                                   *
' * Schede: GMM 4620 + GMB HR168 + K51-AVR                       *
' *   GRIFO(R)   via Dell'Artigiano 8/6                          *
' *   40016 S. Giorgio di Piano (BO)                             *
' *   Tel. +39 051 892052                   Fax. +39 051 893661  *
' *   http://www.grifo.com                  http://www.grifo.it  *
' * by Graziano Gaiba                              10.02.05      *
' ****************************************************************
'
' Questo demo permette di pilotare una periferica I2C BUS a bordo della K51-AVR,
' PCF8574, attraverso il modulo mini-BLOCK GMB HR84 ed un mini modulo grifo(r).
' Il PCF874 e' un I/O expander che permette di pilotare 8 linee digitali TTL sia
' in ingresso che in uscita, tutte le operazioni di lettura e scrittura
' avvengono tramite l'interfaccia seriale sincrona I2C BUS.
' Il demo attiva alternativamente una linea alla volta, creando il classico
' scorrimento di un bit a destra e a sinistra, e scrive 'out' sui display a 7
' segmenti della K51-AVR per indicare il funzionamento del demo.
'
'
' Rel 1.1 - by Graziano Gaiba
' Demo per l'utilizzo del PCF 8574 a bordo della K51-AVR usando una GMB HR168
' pilotata da un Mini Modulo GMM 4620
'
'
' ***************** Definizioni del compilatore ******************
'
DEFINE OSC 10 ' Frequenza oscillatore 9,8304 MHz
DEFINE HSER_RCSTA 90h  ' Abilita EUSART in ricezione
DEFINE HSER_TXSTA 20h  ' Abilita EUSART in trasmissione
DEFINE HSER_BAUD 19200 ' Baud Rate
'
' *************** Dichiarazione delle contanti *******************
'
I2C_BUFFER_SIZE con 10

Saa1064 con $38                 ' Slave address SAA1064
Wsaa1064 con $70                ' Slave address SAA1064 in Write
Rsaa1064 con $71                ' Slave address SAA1064 in Read
'****************** Indirizzi registri Saa1064 ********************
Ctb con 0                       ' Registro di controllo
Dig1 con 1                      ' Cifra 1
Dig2 Con 2                      ' Cifra 2
Dig3 Con 3                      ' Cifra 3
Dig4 Con 4                      ' Cifra 4
'
' **********************************************************************
'
'Pcf8574 con $3C                 ' Slave address PCF8574A
'Wpcf8574 con $78                ' Slave address PCF8574A in scrittura
'Rpcf8574 con $79                ' Slave address PCF8574A in lettura

Pcf8574 con $24                 ' Slave address PCF8574P
Wpcf8574 con $48                ' Slave address PCF8574P in scrittura
Rpcf8574 con $49                ' Slave address PCF8574P in lettura
'
'
' ******************* Dichiarazione delle Variabili ********************
'
' Variabili di uso generico
i var byte
c var byte
scelta var byte
di var byte
do var byte
'
' Usata dalle procedure di gestione I/O
port_val var byte  ' Valore letto o da scrivere nell'I/O
'
' Usate per la gestione dell'I2C BUS hardware
i2c_buffer var byte[I2C_BUFFER_SIZE]
i2c_to_send var byte
i2c_to_receive var byte
i2c_val var byte
i2c_data var byte
i2c_slave var byte
i2c_addr var byte
i2c_cnt var byte
'
' Usate per la visualizzazione su display a 7 segmenti
Figure var byte
Nibble_h var byte
Nibble_l var byte
'
'
' ********************** Programma principale ***************************
'
main:
    gosub Init_cpu
    ' Spegne i relays
    port_val = 0
    gosub set_relays
    ' Inizializza la periferica hardware I2C BUS
    gosub i2cbusinit
    ' Inizializza le periferiche a bordo della K51-AVR
    gosub k51_init
    ' Pulisce lo schermo
    gosub clrscr
    hserout ["Esegue uno shift dei bit del PCF 8574 su CN1...",13,10]
for_ever:

    do = 1

    for i = 1 to 7
' Imposta lo stato dei segnali TTL di ingresso del PCF 8574
        gosub i2cbusstart
        i2c_data = wpcf8574
        gosub i2cbussend
        i2c_data = do ^ $FF
        gosub i2cbussend
        gosub i2cbusstop
        
        do = do << 1
        pause 1000
    next i

    for i = 1 to 7
' Imposta lo stato dei segnali TTL di ingresso del PCF 8574
        gosub i2cbusstart
        i2c_data = wpcf8574
        gosub i2cbussend
        i2c_data = do ^ $FF
        gosub i2cbussend
        gosub i2cbusstop
        
        do = do >> 1
        pause 1000
    next i

   
    goto for_ever
end
'
' ******************* Definizione delle procedure *********************
'
'
' Inizializzazione direzione segnali della CPU
Init_cpu:
    ADCON1=$0f        ' Imposta come I/O digitale i pin AN0..12
    CMCON=$07         ' Imposta come I/O digitale RA0..4
    ' Gli ingressi optoisolati di CN1 sono:
    ' IN1-1 <-> RA0
    ' IN2-1 <-> RA1
    ' IN3-1 <-> RB0
    ' IN4-1 <-> RB1
    ' IN5-1 <-> RA4
    ' IN6-1 <-> RC0
    ' IN7-1 <-> RC1
    ' IN8-1 <-> RC5
    trisa.0 = 1
    trisa.1 = 1
    trisa.4 = 1
    trisb.0 = 1
    trisb.1 = 1
    trisc.0 = 1
    trisc.1 = 1
    trisc.5 = 1
    ' Gli ingressi optoisolati di CN2 sono:
    ' IN1-2 <-> RD0
    ' IN2-2 <-> RD1
    ' IN3-2 <-> RD2
    ' IN4-2 <-> RD3
    ' IN5-2 <-> RD4
    ' IN6-2 <-> RD5
    ' IN7-2 <-> RD6
    ' IN8-2 <-> RD7
    trisd = $ff
    ' Le uscite relays di CN3 sono:
    ' OUT A1 <-> RB4
    ' OUT A2 <-> RB5
    ' OUT B1 <-> RB6
    ' OUT B2 <-> RB7
    ' OUT C1 <-> RB3
    ' OUT C2 <-> RB2
    trisb = trisb & $03
    ' Le uscite relays di CN4 sono:
    ' OUT D1 <-> RA3
    ' OUT D2 <-> RC2 (J10 in posizione 3-4)
    trisa.3 = 0
    trisc.2 = 0
return
'
'
' Pulisce lo schermo, inviando 25 volte CR + LF.
clrscr:
    for i= 0 to 24
      hserout [13, 10]
    next i
return
'
'
' Chiede la pressione di un tasto
chiede_tasto:
    hserout ["Premere un tasto..."]
chiede_tasto_loop:
    hserin 1, chiede_tasto_loop, [i]
return
'
'
' Procedura per impostare lo stato dei relays sui connettori CN3 e CN4.
' A seconda del valore dei bits di port_val, ogni relay viene attivato
' (contatto chiuso) o disattivato (contatto aperto).
' I bit di port_val hanno il seguente significato:
' -- CN3
' port_val.0 pilota il relay OUT A1
' port_val.1 pilota il relay OUT A2
' port_val.2 pilota il relay OUT B1
' port_val.3 pilota il relay OUT B2
' port_val.4 pilota il relay OUT C1
' port_val.5 pilota il relay OUT C2
' -- CN4
' port_val.6 pilota il relay OUT D1
' port_val.7 pilota il relay OUT D2
'
' Ogni bit ha il seguente significato:
'   bit              Significato
'    0    Relay disattivato (contatto aperto)
'    1    Relay attivato (contatto chiuso)
set_relays:
    ' I relays sono pilotati in logica complementata , quindi anche port_val
    ' deve essere complementato
    port_val = port_val ^ $ff
    portb.4 = port_val.0
    portb.5 = port_val.1
    portb.6 = port_val.2
    portb.7 = port_val.3
    portb.3 = port_val.4
    portb.2 = port_val.5
    
    porta.3 = port_val.6
    
    portc.2 = port_val.7
return
'
'
' Inizializza I2C BUS hardware
I2CBUSInit:
        '
        ' Inizializza  I2C BUS
        ' Configura RC3 e RC4 come inputs
        trisc.3 = 1
        trisc.4 = 1
        ' Abilita modula SSP in master I2C BUS mode, clock 50 kHz
        sspstat.6 = 0
        sspadd = $32
        sspcon1 = $28
    return
'                    
'
' Genera I2C BUS start
I2CBUSStart:
        sspcon2.0 = 1
I2CBUSStartLoop:
        if sspcon2.0 = 1 then I2CBUSStartLoop
        pir1.3 = 0
    return
'
'
' Genera I2C BUS start ripetuta
I2CBUSRepStart:
        sspcon2.1 = 1
I2CBUSRepStartLoop:
        if sspcon2.1 = 1 then I2CBUSRepStartLoop
        pir1.3 = 0
    return
'
'
' Genera I2C BUS stop
I2CBUSStop:
        sspcon2.2 = 1
I2CBUSStopLoop:
        if sspcon2.2 = 1 then I2CBUSStopLoop
        pir1.3 = 0
    return
' 
'
' Invia il contenuto della variabile i2c_data all'I2C BUS
I2CBUSSend:
        sspbuf = i2c_data
I2CBUSSendSynch:        
' Attende completamento dell'ultima operaziane dell'interfaccia hardware I2C
        if pir1.3 = 0 then I2CBUSSendSynch
        pir1.3 = 0
    return
' 
'
' Legge un dato da I2C BUS e lo restituisce nella variabile i2c_data
I2CBUSGet:
        sspcon2.3 = 1
I2CBusGetLoop:
        if sspcon2.3 = 1 then I2CBusGetLoop
        i2c_data = sspbuf
I2CBUSGetSynch:        
' Attende completamento dell'ultima operaziane dell'interfaccia hardware I2C
        if pir1.3 = 0 then I2CBUSGetSynch
        pir1.3 = 0
    return
'
'
' Invia NOT acknowledge
I2CBUSNACK:
        ' Invia NOT acknowledge...
        sspcon2.5 = 1
        sspcon2.4 = 1
' Attende completamento dell'ultima operaziane dell'interfaccia hardware I2C
I2CBUSNACKSynch:
        if pir1.3 = 0 then I2CBUSNACKSynch
        pir1.3 = 0
    return
'
'
' Invia acknowledge
I2CBUSACK:
        ' Invia acknowledge...
        sspcon2.5 = 0
        sspcon2.4 = 1
' Attende completamento dell'ultima operaziane dell'interfaccia hardware I2C
I2CBUSACKSynch:
        if pir1.3 = 0 then I2CBUSNACKSynch
        pir1.3 = 0
    return
'
'
' Indica che un acknowledge atteso non e' stato ricevuto.
I2CBUSNotAck:
        hserout ["Acknowledge non ricevuto.", 13, 10]
        ' Disabilita I2CBUS
        sspcon1.5 = 0
    return

'
'
' Legge un byte dal dispositivo il cui slave address e' contenuto nella
' variable i2c_slave e il cui indirizzo e' contenuto nella variabile i2c_addr.
' Il dato letto viene messo nella variabile i2c_val.
I2CBUSReadByte:
        '
        ' Genera I2CBUS Start.
        gosub i2cbusstart
        ' Invia Slave Address
        i2c_data = i2c_slave
        gosub i2cbussend
        ' Se acknowledge non ricevuto, segnala un errore
        if sspcon2.6 = 1 then I2CBUSNotAck
        ' Invia indirizzo
        i2c_data = i2c_addr
        gosub i2cbussend
        ' Se acknowledge non ricevuto, segnala un errore
        if sspcon2.6 = 1 then I2CBUSNotAck
        ' Genera I2CBUS Start ripetuto
        gosub i2cbusrepstart
        ' Invia Slave Address per la lettura
        i2c_data = i2c_slave | $01
        gosub i2cbussend
        ' Se acknowledge non ricevuto, segnala un errore
        if sspcon2.6 = 1 then I2CBUSNotAck
        ' ricewve il dato
        gosub i2cbusget
        i2c_val = i2c_data
        ' Invia NOT acknowledge.
        gosub I2CBUSNACK
        ' Genera stop
        gosub i2cbusstop
    return
'
'
' Scrive un byte al dispositivo il cui slave address e' contenuto nella
' variablie i2c_slave e il cui indirizzo e' contenuto nella variabile i2c_addr.
' Il dato da scrivere viene messo nella variabile i2c_val.
I2CBUSWriteByte:
        '
        ' Genera I2CBUS Start.
        gosub i2cbusstart
        ' Invia Slave Address per scrittura
        i2c_data = i2c_slave
        gosub i2cbussend
        ' Se acknowledge non ricevuto, segnala un errore
        if sspcon2.6 = 1 then I2CBUSNotAck
        ' Invia indirizzo
        i2c_data = i2c_addr
        gosub i2cbussend
        ' Se acknowledge non ricevuto, segnala un errore
        if sspcon2.6 = 1 then I2CBUSNotAck
        ' Invia dato
        i2c_data = i2c_val
        gosub i2cbussend
        ' Se acknowledge non ricevuto, segnala un errore
        if sspcon2.6 = 1 then I2CBUSNotAck
        ' Genera stop
        gosub i2cbusstop
    return
'
'
' Invia una sequenza di bytes ad un dispositivo I2C BUS.
' Lo slave address deve essere contentuo nella variabile i2c_slave.
' I dati da inviare vanno memorizzati nell'array i2c_buffer. 
' L'utente puo' cambiare la dimensione dell'array modificando I2C_BUFFER_SIZE.
' Il numero di bytes da inviare va memorizzato nella variabile i2c_to_send.
' L'utente deve verifcare che non avvengano eventuali overflows.
I2CBUSWrite:
        '
        ' Genera I2CBUS Start.
        gosub i2cbusstart
        ' Invia Slave Address in scrittura
        i2c_data = i2c_slave
        gosub i2cbussend
        ' Se acknowledge non ricevuto, segnala un errore
        if sspcon2.6 = 1 then I2CBUSNotAck
        for i2c_cnt = 0 to i2c_to_send - 1
            ' Invia dati
            i2c_data = i2c_buffer[i2c_cnt]
            gosub i2cbussend
            ' Se acknowledge non ricevuto, segnala un errore
            if sspcon2.6 = 1 then I2CBUSNotAck
        next i2c_cnt
        ' Genera stop
        gosub i2cbusstop
    return
'
'
' Legge una sequenza di bytes da un dispositivo I2C BUS.
' Lo slave address deve essere contentuo nella variabile i2c_slave.
' I dati da inviare vanno memorizzati nell'array i2c_buffer. 
' L'utente puo' cambiare la dimensione dell'array modificando I2C_BUFFER_SIZE.
' I dati ricevuti vengono memorizzati nello stesso array.
' Il numero di bytes da inviare va memorizzato nella variabile i2c_to_send.
' Il numero di bytes da ricevere va memorizzato nella variabile i2c_to_receive.
' L'utente deve verifcare che non avvengano eventuali overflows.
I2CBUSRead:
        '
        ' Generat I2CBUS Start.
        gosub i2cbusstart
        ' Invia Slave Address in scrittura
        i2c_data = i2c_slave
        gosub i2cbussend
        ' Se acknowledge non ricevuto, segnala un errore
        if sspcon2.6 = 1 then I2CBUSNotAck
        for i2c_cnt = 0 to i2c_to_send - 1
            ' Invia dati
            i2c_data = i2c_buffer[i2c_cnt]
            gosub i2cbussend
            ' Se acknowledge non ricevuto, segnala un errore
            if sspcon2.6 = 1 then I2CBUSNotAck
        next i2c_cnt
        ' Genera I2CBUS Start ripetuto.
        gosub i2cbusrepstart
        ' Invia Slave Address in lettura
        i2c_data = i2c_slave | $01
        gosub i2cbussend
        ' Se acknowledge non ricevuto, segnala un errore
        if sspcon2.6 = 1 then I2CBUSNotAck
        for i2c_cnt = 0 to i2c_to_receive - 1
            ' Legge i dati
            gosub i2cbusget
            i2c_buffer[i2c_cnt] = i2c_data
            if i2c_cnt == i2c_to_receive - 1 then
               ' Invia NOT acknowledge.
                gosub I2CBUSNACK
            else
               ' Invia acknowledge.
                gosub I2CBUSaCK
            endif
        next i2c_cnt
        ' Invia lo stop
        gosub i2cbusstop
    return
' 
' 
' Inizializzazione delle periferiche a bordo della K51-AVR
K51_init:   
        '
        ' Configurazione del controller dei display a 7 segmenti SAA 1064
        '
        gosub i2cbusstart
        i2c_data = rsaa1064
        gosub i2cbussend
        gosub i2cbusget
        gosub i2cbusnack
        gosub i2cbusstop
        if i2c_data <> 0 then k51_init
        '
        i2c_slave = wsaa1064
        i2c_buffer[0] = ctb               ' Punta al registro di controllo
        i2c_buffer[1] =  %00100111        ' bit0 =1 dynamic mode
                                          ' bit1 =1 cifre 1+3 non spente
                                          ' bit2 =1 cifre 2+4 non spente
                                          ' bit3 =0 no test segmenti
                                          ' bit4 =0 no corrente segmenti 3mA  
                                          ' bit5 =1 corrente segmenti 6mA
                                          ' bit6 =0 no corrente segmenti 12mA
                                          ' bit7 =0 indifferente
        i2c_buffer[2] = 92                ' Scrive 'o'
        i2c_buffer[3] = 28                ' Scrive 'u'
        i2c_buffer[4] = 120               ' Scrive 't'
        i2c_buffer[5] = 0
        i2c_to_send = 6
        gosub i2cbuswrite
    return