' ****************************************************************
' * File:  gmbiot.bas  -  Ver. 1.1                               *
' * Compilatore:  PIC Basic PRO                                  *
' * IDE: MicroCode Studio Plus                                   *
' * Versione Compilatore: 2.45                                   *
' * Schede: GMM 4620 + GMB HR168 + K51-AVR                       *
' *   GRIFO(R)   via Dell'Artigiano 8/6                          *
' *   40016 S. Giorgio di Piano (BO)                             *
' *   Tel. +39 051 892052                   Fax. +39 051 893661  *
' *   http://www.grifo.com                  http://www.grifo.it  *
' * by Graziano Gaiba                              11.02.05      *
' ****************************************************************
'
' Questo Demo permette di utilizzare immediatamente le linee di I/O digitale
' TTL presenti su CN7. Alla partenza viene presentata la lista delle linee
' disponibili.
' Una Volta Selezionata Quella d'interesse la si puo' gestire in input
' (rappresentando Il Suo Stato Sulla Console) o in output
' (settandola alta o bassa).
'
'
' Rel 1.1 - by Graziano Gaiba
' Demo di utilizzo dei segnali TTL I/O digitali usando una GMB HR168
' pilotata da un Mini Modulo GMM 4620
'
'
' ***************** Definizioni del compilatore ******************
'
DEFINE OSC 10 ' Frequenza oscillatore 9,8304 MHz
DEFINE HSER_RCSTA 90h  ' Abilita EUSART in ricezione
DEFINE HSER_TXSTA 20h  ' Abilita EUSART in trasmissione
DEFINE HSER_BAUD 19200 ' Baud Rate
'
' *************** Dichiarazione delle contanti *******************
'
RTCSLA con $A0
I2C_BUFFER_SIZE con 10
'
' ******************* Dichiarazione delle Variabili ********************
'
' Variabili di uso generico
i var byte
scelta var byte
di var byte
do var byte
'
' Usata dalle procedure di gestione I/O
port_val var byte  ' Valore letto o da scrivere nell'I/O
'
'
'
'********************** Programma principale ***************************
'
main:
    gosub Init_cpu
    ' Spegne i relays
    port_val = 0
    gosub set_relays
for_ever:
    gosub clrscr
    hserout ["Demo TTL I/O su CN7 Rel 1.1 per GMM 4620 rel 120304 e GMB HR168 rel 110104", 13, 10, 13, 10]
    hserout ["Se un segnale viene scelto come ingresso, viene visualizzato continuamente.", 13, 10]
    hserout ["Se viene scelto come uscita, premendo 1 va alto, 0 va basso, oppure esce.", 13, 10, 13 ,10]
    hserout ["1) pin 2 di CN7", 13, 10] ' RE0
    hserout ["2) pin 3 di CN7", 13, 10] ' RE1
    hserout ["3) pin 4 di CN7", 13, 10] ' /INTRTC
    hserout ["4) pin 6 di CN7", 13, 10] ' RC2
    hserout ["5) pin 8 di CN7", 13, 10] ' RA5
    hserout [13, 10, "Scelta: "]
input_scelta:
    hserin [dec1 scelta]
    if scelta < 1 and scelta > 5 then input_scelta
    hserout [dec1 scelta, 13, 10]
    hserout [13, 10]
    hserout ["1) Input", 13, 10]
    hserout ["2) Output", 13, 10]
input_scelta_dir:
    hserin [dec1 i]
    if i < 1 and i > 2 then input_scelta_dir
    if i = 1 then
        hserout [13, 10, "Input", 13, 10]
    else
        hserout [13, 10, "Output", 13, 10]
    endif
scelta_loop:
    hserout [13, 10]
    ' pin 2 di CN7 - RE0
    if scelta = 1 then
        if i = 1 then
            trise.0 = 1
scelta_loop_1:
            hserout ["Stato: ", dec1 porte.0, 13]
            hserin 50, scelta_loop_1, [di]
        else
            trise.0 = 0
            hserout ["Stato: "]
            hserin [dec1 do]
            hserout [dec1 do]
            if do <> 0 and do <> 1 then for_ever
            porte.0 = do
            goto scelta_loop
        endif
    endif
    ' pin 3 di CN7 - RE1
    if scelta = 2 then
        if i = 1 then
            trise.1 = 1
scelta_loop_2:
            hserout ["Stato: ", dec1 porte.1, 13]
            hserin 50, scelta_loop_2, [di]
        else
            trise.1 = 0
            hserout ["Stato: "]
            hserin [dec1 do]
            hserout [dec1 do]
            if do <> 0 and do <> 1 then for_ever
            porte.1 = do
            goto scelta_loop
        endif
    endif
    ' pin 4 di CN7 - /INTRTC    
    if scelta = 3 then
       hserout ["Pin 4 e' collegato all'interrupt del Real Time Clock . Puo':", 13, 10]
       hserout ["generare onde quadre; attivare ogni decimo,secondo,minuto,ora,giorno", 13, 10]
       hserout ["un interrupt.", 13, 10]
       hserout ["Il LED LD28 ne mostra lo stato.", 13, 10]
       gosub chiede_tasto
    endif
    ' pin 6 di CN7 - RC2
    if scelta = 4 then
        if i = 1 then
            trisc.2 = 1
scelta_loop_3:
            hserout ["Stato: ", dec1 portc.2, 13]
            hserin 50, scelta_loop_3, [di]
        else
            trisc.2 = 0
            hserout ["Stato: "]
            hserin [dec1 do]
            hserout [dec1 do]
            if do <> 0 and do <> 1 then for_ever
            portc.2 = do
            goto scelta_loop
        endif
    endif
    ' pin 8 di CN7 - RA5
    if scelta = 5 then
        if i = 1 then
            trisa.5 = 1
scelta_loop_4:
            hserout ["Stato: ", dec1 porta.5, 13]
            hserin 50, scelta_loop_4, [di]
        else
            trisa.5 = 0
            hserout ["Stato: "]
            hserin [dec1 do]
            hserout [dec1 do]
            if do <> 0 and do <> 1 then for_ever
            porta.5 = do
            goto scelta_loop
        endif
    endif
    
    goto for_ever
end
'
' **************** Procedures definition ******************
'
'
' Inizializzazione direzione segnali della CPU
Init_cpu:
    ADCON1=$0f        ' Imposta come I/O digitale i pin AN0..12
    CMCON=$07         ' Imposta come I/O digitale RA0..4
    ' Gli ingressi optoisolati di CN1 sono:
    ' IN1-1 <-> RA0
    ' IN2-1 <-> RA1
    ' IN3-1 <-> RB0
    ' IN4-1 <-> RB1
    ' IN5-1 <-> RA4
    ' IN6-1 <-> RC0
    ' IN7-1 <-> RC1
    ' IN8-1 <-> RC5
    trisa.0 = 1
    trisa.1 = 1
    trisa.4 = 1
    trisb.0 = 1
    trisb.1 = 1
    trisc.0 = 1
    trisc.1 = 1
    trisc.5 = 1
    ' Gli ingressi optoisolati di CN2 sono:
    ' IN1-2 <-> RD0
    ' IN2-2 <-> RD1
    ' IN3-2 <-> RD2
    ' IN4-2 <-> RD3
    ' IN5-2 <-> RD4
    ' IN6-2 <-> RD5
    ' IN7-2 <-> RD6
    ' IN8-2 <-> RD7
    trisd = $ff
    ' Le uscite relays di CN3 sono:
    ' OUT A1 <-> RB4
    ' OUT A2 <-> RB5
    ' OUT B1 <-> RB6
    ' OUT B2 <-> RB7
    ' OUT C1 <-> RB3
    ' OUT C2 <-> RB2
    trisb = trisb & $03
    ' Le uscite relays di CN4 sono:
    ' OUT D1 <-> RA3
    ' OUT D2 <-> RC2 (J10 in posizione 3-4)
    trisa.3 = 0
    trisc.2 = 0
return
'
'
' Pulisce lo schermo, inviando 25 volte CR + LF.
clrscr:
    for i= 0 to 24
      hserout [13, 10]
    next i
return
'
'
' Chiede la pressione di un tasto
chiede_tasto:
    hserout ["Premere un tasto..."]
chiede_tasto_loop:
    hserin 1, chiede_tasto_loop, [i]
return
'
'
' Procedura per impostare lo stato dei relays sui connettori CN3 e CN4.
' A seconda del valore dei bits di port_val, ogni relay viene attivato
' (contatto chiuso) o disattivato (contatto aperto).
' I bit di port_val hanno il seguente significato:
' -- CN3
' port_val.0 pilota il relay OUT A1
' port_val.1 pilota il relay OUT A2
' port_val.2 pilota il relay OUT B1
' port_val.3 pilota il relay OUT B2
' port_val.4 pilota il relay OUT C1
' port_val.5 pilota il relay OUT C2
' -- CN4
' port_val.6 pilota il relay OUT D1
' port_val.7 pilota il relay OUT D2
'
' Ogni bit ha il seguente significato:
'   bit              Significato
'    0    Relay disattivato (contatto aperto)
'    1    Relay attivato (contatto chiuso)
set_relays:
    ' I relays sono pilotati in logica complementata , quindi anche port_val
    ' deve essere complementato
    port_val = port_val ^ $ff
    portb.4 = port_val.0
    portb.5 = port_val.1
    portb.6 = port_val.2
    portb.7 = port_val.3
    portb.3 = port_val.4
    portb.2 = port_val.5
    
    porta.3 = port_val.6
    
    portc.2 = port_val.7
return