' ****************************************************************
' * File:  gmbda.bas  -  Ver. 1.1                                *
' * Compilatore:  PIC Basic PRO                                  *
' * IDE: MicroCode Studio Plus                                   *
' * Versione Compilatore: 2.45                                   *
' * Schede: GMM 4620 + GMB HR168 + K51-AVR                       *
' *   GRIFO(R)   via Dell'Artigiano 8/6                          *
' *   40016 S. Giorgio di Piano (BO)                             *
' *   Tel. +39 051 892052                   Fax. +39 051 893661  *
' *   http://www.grifo.com                  http://www.grifo.it  *
' * by Graziano Gaiba                              10.02.05      *
' ****************************************************************
'
' Il demo utilizza la sezione CCP1 Mini Modulo per generare, su CN7,
' un segnale PWM di frequenza prestabilita, con duty cycle programmabile in
' percentuale da console. Tale segnale, collegato ad una opportuna circuiteria
' integratrice (rete RC, amplificatore operazionale con capacita' su ramo di
' retroazione, ecc.) permette di ottenere un segnale analogico analogo a quello
' di un D/A. L'esecuzione del demo e' subordinata al Mini Modulo utilizzato e
' alla configurazione della linea seriale.
'
' Rel 1.1 - by Graziano Gaiba
' Demo per generazione segnali PWM usando una GMB HR168
' pilotata da un Mini Modulo GMM 4620
'
'
' ***************** Definizioni del compilatore ******************
'
DEFINE OSC 10 ' Frequenza oscillatore 9,8304 MHz
DEFINE HSER_RCSTA 90h  ' Abilita EUSART in ricezione
DEFINE HSER_TXSTA 20h  ' Abilita EUSART in trasmissione
DEFINE HSER_BAUD 19200 ' Baud Rate
'
' *************** Dichiarazione delle contanti *******************
'
RTCSLA con $A0
I2C_BUFFER_SIZE con 10
'
' ******************* Dichiarazione delle Variabili ********************
'
' Variabili di uso generico
i var byte
scelta var byte
di var byte
do var byte
'
' Usata dalle procedure di gestione I/O
port_val var byte  ' Valore letto o da scrivere nell'I/O
'
' Usata nella gestione del demo PWM
duty_cycle var word
'
'
'********************** Programma principale ***************************
'
main:
    gosub Init_cpu
    ' Spegne i relays
    port_val = 0
    gosub set_relays
    gosub clrscr
    hserout ["Demo PWM Rel 1.1 per GMM 4620 rel 120304 e GMB HR168 rel 110104", 13, 10, 13, 10]
    hserout ["Questo demo genera un segnale PWM a circa 10 kHz sul pin 6 di CN7.", 13, 10]
    hserout ["Per un corretto funzionamento, il pin 6 di CN7 NON deve essere connesso al", 13, 10]
    hserout ["relay OUT D2 alla sezione RS 485 per cui J10 va connesso in 1-2 e 4-5.", 13, 10]
    gosub chiede_tasto
    hserout [13, 10, 13, 10]
    ' Prescaler di Timer 2 impostato 1
    t2con = 0
    ' Pin CCP1 impostato come uscita
    trisc.2 = 0
    ' Modulo CCP1 in CCP standard PWM mode
    eccp1con = $0f
    ' Circa 10 KHz di frequenza per il segnale PWM
    pr2 = $ff
    ' Attiva timer 2, timer 2 viene usato come base dei tempi per PWM dei CCP
    t2con.2 = 1
for_ever:
    hserout ["Duty cycle (MAIUSCOLO esadecimale da 0 a 03FF): "]
    hserin [hex4 duty_cycle]
    hserout [hex4 duty_cycle, 13, 10]
    if duty_cycle > $3ff then for_ever
    eccp1con.4 = duty_cycle.0
    eccp1con.5 = duty_cycle.1
    ccpr1l = duty_cycle.lowbyte >> 2
    ccpr1l.6 = duty_cycle.8
    ccpr1l.7 = duty_cycle.9
    
    goto for_ever
end
'
' **************** Procedures definition ******************
'
'
' Inizializzazione direzione segnali della CPU
Init_cpu:
    ADCON1=$0f        ' Imposta come I/O digitale i pin AN0..12
    CMCON=$07         ' Imposta come I/O digitale RA0..4
    ' Gli ingressi optoisolati di CN1 sono:
    ' IN1-1 <-> RA0
    ' IN2-1 <-> RA1
    ' IN3-1 <-> RB0
    ' IN4-1 <-> RB1
    ' IN5-1 <-> RA4
    ' IN6-1 <-> RC0
    ' IN7-1 <-> RC1
    ' IN8-1 <-> RC5
    trisa.0 = 1
    trisa.1 = 1
    trisa.4 = 1
    trisb.0 = 1
    trisb.1 = 1
    trisc.0 = 1
    trisc.1 = 1
    trisc.5 = 1
    ' Gli ingressi optoisolati di CN2 sono:
    ' IN1-2 <-> RD0
    ' IN2-2 <-> RD1
    ' IN3-2 <-> RD2
    ' IN4-2 <-> RD3
    ' IN5-2 <-> RD4
    ' IN6-2 <-> RD5
    ' IN7-2 <-> RD6
    ' IN8-2 <-> RD7
    trisd = $ff
    ' Le uscite relays di CN3 sono:
    ' OUT A1 <-> RB4
    ' OUT A2 <-> RB5
    ' OUT B1 <-> RB6
    ' OUT B2 <-> RB7
    ' OUT C1 <-> RB3
    ' OUT C2 <-> RB2
    trisb = trisb & $03
    ' Le uscite relays di CN4 sono:
    ' OUT D1 <-> RA3
    ' OUT D2 <-> RC2 (J10 in posizione 3-4)
    trisa.3 = 0
    trisc.2 = 0
return
'
'
' Pulisce lo schermo, inviando 25 volte CR + LF.
clrscr:
    for i= 0 to 24
      hserout [13, 10]
    next i
return
'
'
' Chiede la pressione di un tasto
chiede_tasto:
    hserout ["Premere un tasto..."]
chiede_tasto_loop:
    hserin 1, chiede_tasto_loop, [i]
return
'
'
' Procedura per impostare lo stato dei relays sui connettori CN3 e CN4.
' A seconda del valore dei bits di port_val, ogni relay viene attivato
' (contatto chiuso) o disattivato (contatto aperto).
' I bit di port_val hanno il seguente significato:
' -- CN3
' port_val.0 pilota il relay OUT A1
' port_val.1 pilota il relay OUT A2
' port_val.2 pilota il relay OUT B1
' port_val.3 pilota il relay OUT B2
' port_val.4 pilota il relay OUT C1
' port_val.5 pilota il relay OUT C2
' -- CN4
' port_val.6 pilota il relay OUT D1
' port_val.7 pilota il relay OUT D2
'
' Ogni bit ha il seguente significato:
'   bit              Significato
'    0    Relay disattivato (contatto aperto)
'    1    Relay attivato (contatto chiuso)
set_relays:
    ' I relays sono pilotati in logica complementata , quindi anche port_val
    ' deve essere complementato
    port_val = port_val ^ $ff
    portb.4 = port_val.0
    portb.5 = port_val.1
    portb.6 = port_val.2
    portb.7 = port_val.3
    portb.3 = port_val.4
    portb.2 = port_val.5
    
    porta.3 = port_val.6
    
    portc.2 = port_val.7
return