5
10 REM ********************************************************************
20 REM *        Programma S2DEB7 Rel 1.0 utilizzando MCS BASIC 52         *
15 REM *                  per le schede GPCF2 e DEB01                     *
30 REM *       GRIFO(R)  via Dante, 1      40016 S.Giorgio di Piano (BO)  *
40 REM *       Tel.(051)89.20.52           FAX.(051)89.86.61              *
50 REM *                                                                  *
60 REM * Emula un cronometro visualizzato sui display a bordo della       *
70 REM * DEB01 , mantre i tasti da utilizzare sono quelli del tastierino  *
80 REM *                                                                  *
90 REM * by Pedrielli Adriano.           20 AGOSTO 1991                   *
95 REM ********************************************************************
100 REM                                                                     
102 REM Per il collegamento fra le due schede occorre un flat inserito nel
103 REM connettore CN2 da 20 vie della GPCF2 e nel connettore CN4 della 
104 REM DEB01
105 REM 
110 REM ************************* Main program *************************
120 REM ********** Inizializzo port A in out ,port C meta in input e out
130 XBY(64003)=129
140 REM ********** Spengo i segmenti
150 XBY(64000)=255
155 PRINT " TASTO -C- (START STOP) IL TASTO -D- (RESET LAP) "
160 REM ********** Visualizzazione display
165 A2=192 :B2=192 :C2=192 :D2=192
167 A=0:B=0:C=0:D=0
170 X=0
172 X=X+1 : XBY(64002)=16 : XBY(64000)=D2 : XBY(64000)=255
180 XBY(64002)=32 : XBY(64000)=C2 : XBY(64000)=255
190 XBY(64002)=64 : XBY(64000)=B2 : XBY(64000)=255
200 XBY(64002)=128: XBY(64000)=A2 : XBY(64000)=255
202 K=XBY(64002)
203 IF K<143.AND.K>140 THEN GOTO 700
204 H=0
205 IF X<2 THEN  GOTO 172
207 IF L<>1 THEN GOTO 170
210 REM ********************** CONTEGGIO ****************************
220 A=A+1
230 IF A=10 THEN  GOTO 260
240 IF Y<>0 THEN GOSUB 500 :GOTO 170
245 Z=A :  GOSUB 500 :A2=Z
250 GOTO 170
260 IF Y<>0 THEN GOTO 270 ELSE A2=192
270 A=0 :B=B+1
280 IF B=10 THEN  GOTO 310
290 IF Y<>0 THEN GOSUB 500 :GOTO 170
295 Z=B :  GOSUB 500 :B2=Z
300 GOTO 170
310 IF Y<>0 THEN GOTO 315 ELSE B2=192
315 B=0 :C=C+1
320 IF C=6 THEN  GOTO 360
340 IF Y<>0 THEN GOSUB 500 :GOTO 170
345 Z=C :  GOSUB 500 :C2=Z
350 GOTO 170
360 IF Y<>0 THEN GOTO 365 ELSE C2=192
365 C=0 :D=D+1
370 IF D=10 THEN  GOTO 165
390 IF Y<>0 THEN GOSUB 500 :GOTO 170
395 Z=D :  GOSUB 500 :D2=Z
400 GOTO 170
410 REM ****************** TABELLA CONVERSIONE *******************
500 IF Z=0 THEN Z=192
510 IF Z=1 THEN Z=249
520 IF Z=2 THEN Z=164
530 IF Z=3 THEN Z=176
540 IF Z=4 THEN Z=153
550 IF Z=5 THEN Z=146
560 IF Z=6 THEN Z=130
570 IF Z=7 THEN Z=216
580 IF Z=8 THEN Z=128
590 IF Z=9 THEN Z=144
595 RETURN
606 REM
608 REM ************ Identificazione tasto premuto ***********
609 REM
700 IF H=K THEN GOTO 205 ELSE H=K
705 IF K=142.AND.L=0 THEN L=1 :GOTO 205 : REM ************** TASTO C
720 IF K=142.AND.L=1 THEN L=0 :GOTO 205
740 IF K=141.AND.L=0.AND.Y=0 THEN GOTO 160 ELSE GOTO 745 :REM ** TASTO D
745 IF K=141.AND.Y=0.AND.L=1 THEN Y=1 :GOTO 205
760 IF K=141.AND.Y=1 THEN Y=0 ELSE GOTO 205
770 Z=A:GOSUB 500:A2=Z:Z=B:GOSUB 500:B2=Z
775 Z=C:GOSUB 500:C2=Z: Z=D :GOSUB 500:D2=Z
780 GOTO 205