5
10 REM ********************************************************************
20 REM *        Programma S2DEB5 Rel 1.0 utilizzando MCS BASIC 52         *
15 REM *                  per le schede GPCF2 e DEB01                     *
30 REM *       GRIFO(R)  via Dante, 1      40016 S.Giorgio di Piano (BO)  *
40 REM *       Tel.(051)89.20.52           FAX.(051)89.86.61              *
50 REM *                                                                  *
60 REM * Visualizza sul display i dati immessi dalla tastiera esadecimale *
80 REM *                                                                  *
90 REM * by Pedrielli Adriano.           20 AGOSTO 1991                   *
95 REM ********************************************************************
100 REM                                                                     
102 REM Per il collegamento fra le due schede occorre un flat inserito nel
103 REM connettore CN2 da 20 vie della GPCF2 e nel connettore CN4 della 
104 REM DEB01
105 REM 
110 REM ************************* Main program *************************
120 REM ********** Inizializzo port A in out ,port C meta input e out
130 XBY(64003)=129
135 A3=255 : B2=255 : C2=255 : D2=255
140 REM ********** Spengo i segmenti
150 XBY(64000)=255
160 REM ********** Visualizzazione display e scanning tastiera *********
170 XBY(64002)=16 : XBY(64000)=D2 
175 A=XBY(64002): XBY(64000)=255
180 XBY(64002)=32 : XBY(64000)=C2
185 F=XBY(64002) : XBY(64000)=255
190 XBY(64002)=64 : XBY(64000)=B2
195 G=XBY(64002) : XBY(64000)=255
200 XBY(64002)=128 : XBY(64000)=A3
201 H=XBY(64002) : XBY(64000)=255
202 IF A<>31 THEN GOTO 220
203 IF F<>47 THEN GOTO 230
204 IF G<>79 THEN GOTO 240
205 IF H<>143 THEN GOTO 250
208 K=0:GOTO 170
210 REM ************* CONTROLLO PRESENZA ALTRO TASTO ***************
220 B=5:GOTO 300
230 A=F:B=6:GOTO 300
240 A=G:B=7:GOTO 300
250 A=H:B=4:GOTO 300
303 C=0
305 XBY(64002)=2**B
310 B=B+1
320 IF B=8 THEN B=4
330 D=XBY(64002) :E=D-(INT(D/16)*16) 
340 IF E<>15 THEN GOTO 170
300 IF A=K THEN GOTO 170  : REM ********** CONTROLLO TASTO PREMUTO
302 K=A
350 C=C+1 :IF C=3 THEN GOTO 360 ELSE GOTO 305
360 IF A<31 THEN GOTO 400
365 IF A>134 THEN GOTO 700
370 IF A>70 THEN GOTO 600
375 IF A>38 THEN GOTO 500
380 REM ********** Tabelle conversioni ************
400 IF A=30 THEN A2=249 : REM ******* TASTO 1
410 IF A=29 THEN A2=153 : REM ******* TASTO 4
420 IF A=27 THEN A2=216 : REM ******* TASTO 7
430 IF A=23 THEN A2=136 : REM ******* TASTO A
440 GOTO 800
500 IF A=46 THEN A2=164 : REM ******* TASTO 2
510 IF A=45 THEN A2=146 : REM ******* TASTO 5
520 IF A=43 THEN A2=128 : REM ******* TASTO 8
530 IF A=39 THEN A2=192 : REM ******* TASTO 0
535 GOTO 800
600 IF A=78 THEN A2=176 : REM ******* TASTO 3
610 IF A=77 THEN A2=130 : REM ******* TASTO 6
620 IF A=75 THEN A2=144 : REM ******* TASTO 9
630 IF A=71 THEN A2=131 : REM ******* TASTO B
635 GOTO 800
700 IF A=141 THEN A2=161: REM ******* TASTO D
710 IF A=142 THEN A2=198: REM ******* TASTO C
720 IF A=139 THEN A2=134: REM ******* TASTO E
730 IF A=135 THEN A2=142: REM ******* TASTO F
740 REM ************** AGGIORNAMENTO DISPLAY ****************
800 D2=C2:C2=B2:B2=A3:A3=A2
810  GOTO 170