5
10 REM ********************************************************************
20 REM *        Programma S2DEB4 Rel 1.0 utilizzando MCS BASIC 52         *
15 REM *                  per le schede GPCF2 e DEB01                     *
30 REM *       GRIFO(R)  via Dante, 1      40016 S.Giorgio di Piano (BO)  *
40 REM *       Tel.(051)89.20.52           FAX.(051)89.86.61              *
50 REM *                                                                  *
60 REM * Effetua un loop di conteggio e lo visualizza sul display         *
80 REM *                                                                  *
90 REM * by Pedrielli Adriano.           20 AGOSTO 1991                   *
95 REM ********************************************************************
100 REM                                                                     
102 REM Per il collegamento fra le due schede occorre un flat inserito nel
103 REM connettore CN2 da 20 vie della GPCF2 e nel connettore CN4 della 
104 REM DEB01
105 REM 
110 REM ************************* Main program *************************
120 REM ********** Inizializzo port A in out ,port C out
130 XBY(64003)=128
135 A2=192 : B2=192 : C2=192 : D2=192
140 REM ********** Spengo i segmenti
150 XBY(64000)=255
160 REM ********** Visualizzazione display
170 X=0
172 X=X+1 : XBY(64002)=16 : XBY(64000)=D2
175 FOR K=0 TO 20 :NEXT K :XBY(64000)=255
180 XBY(64002)=32 : XBY(64000)=C2
185 FOR K=0 TO 20 :NEXT K :XBY(64000)=255
190 XBY(64002)=64 : XBY(64000)=B2 
195 FOR K=0 TO 20 :NEXT K :XBY(64000)=255
200 XBY(64002)=128 : XBY(64000)=A2 
202 FOR K=0 TO 20 :NEXT K :XBY(64000)=255
205 IF X<2 THEN  GOTO 172 ELSE  GOTO 220
210 REM ********************** CONTEGGIO ****************************
220 A=A+1
230 IF A=10 THEN  GOTO 260
240 Z=A :  GOSUB 500
250 A2=Z :  GOTO 170
260 A=0 : A2=192
270 B=B+1
280 IF B=10 THEN  GOTO 310
290 Z=B :  GOSUB 500
300 B2=Z :  GOTO 170
310 B=0 : B2=192
315 C=C+1
320 IF C=10 THEN  GOTO 360
340 Z=C :  GOSUB 500
350 C2=Z :  GOTO 170
360 C=0 : C2=192
365 D=D+1
370 IF D=10 THEN  GOTO 135
390 Z=D :  GOSUB 500
400 D2=Z :  GOTO 170
410 REM ****************** TABELLA CONVERSIONE *******************
500 IF Z=0 THEN Z=192
510 IF Z=1 THEN Z=249
520 IF Z=2 THEN Z=164
530 IF Z=3 THEN Z=176
540 IF Z=4 THEN Z=153
550 IF Z=5 THEN Z=146
560 IF Z=6 THEN Z=130
570 IF Z=7 THEN Z=216
580 IF Z=8 THEN Z=128
590 IF Z=9 THEN Z=144
600 RETURN