; **********************************************************************
; * File  S1DEB9.asm           scheda: GPC 553               con SXA51 *
; * GRIFO(R)   via Dell'Artigiano 8/6   40016 S. Giorgio di Piano (BO) *
; *     Tel. +39 051 892052                        Fax. +39 051 893661 *
; *     http://www.grifo.it                       http://www.grifo.com *
; *     by Alessio Francesconi                            del 27.09.04 *
; **********************************************************************
; Programma di esempio per la sezione 1 della DEB 01, comandata da una 
; GPC 553. Tale sezione è composta da 16 tasti collegati a 16 led:
; la pressione di uno o più di questi tasti determina lo stato logico
; 0 sulla linea, e l'accensione del led corrispondente via hardware.
; Questo programma ha il compito di comunicare con il pc e di far scorrere
; l'accensione di un led da sinistra verso destra e contemporaneamente 
; l'accensione di un led da destra verso sinistra.
; Per i movimenti e posizionamenti del cursore sono state
; adoperate alcune sequenze di comando secondo lo standard ADDS Viewpoint
; (vedi manuale GET51).
; Il collegamento è realizzato tramite un flat 20 vie che congiunge il 
; connettore CN5 della GPC 553 e il connettore CN15 della DEB 01.
;
;               Indirizzi delle periferiche di bordo
;
              PORT1       EQU    00090H              ;registro dati del port 1 del 80c552
              PORT4       EQU    000C0H              ;registro dati del port 4 del 80c552  
	      DSW1 	  EQU	 0FFFCH		     ;registro dati del dip switch
;
;               Gestione memorie
;
              FPORT    EQU   08H                 ;indirizzo di memoria interna contenente il valore rel. del port 4
              SECPORT  EQU   09H	         ;indirizzo di memoria interna contenente il valore rel. del port 1
              TXCHAR   EQU   0DH                 ;indirizzo di memoria contenente il valore da trasmettere sulla seriale
              DELAY    EQU   11H                 ;variabile utilizzata nella procedura di ritardo di 100 usec (DELAY100) 
;
;               Inizio programma (main)
;
                ORG     2050H                   ;Inizio del codice in memoria
		MOV	PORT1,#00H		;setto il port 1 GPC 553 (port 1 DEB 01) in output
		MOV	PORT4,#00H		;setto il port 4 GPC 553 (port 0 DEB 01) in output	
                MOV     SP,#2FH                 ;inizializzo il puntatore della prima locazione libera dello stack
		CLR	RS0			;imposto l'indirizzo di memoria dei registri (00H-07H)
		CLR	RS1                     
                ACALL   SERIAL                  ;inizializza la seriale
		MOV	DPTR,#HEADING    	;stampo a monitor la stringa "HEADING"
		ACALL	STRING      
                MOV	FPORT,#0FEH		;imposto i valori iniziali per entrambi i port
		MOV	SECPORT,#07FH
;
CYCLE:		ACALL	SHIFT			;richiamo la procedura degli shift dei led
		AJMP	CYCLE
;
;              Procedura per la rappresentazione sui Port 0 e 1 del dato acquisito          
;
OUTPORT01:	PUSH	PSW			;salvo i registri utilizzati nella procedura
		PUSH    DPL                     
                PUSH    DPH                     
                PUSH    ACC                     
		MOV	A,FPORT                 ;carico il valore del port 4 da rappresentare in ACC   
          	MOV	PORT4,A			;e lo sparo sul port 0 della DEB 01
		MOV	A,SECPORT               ;carico il valore del port 1 da rappresentare in ACC   
          	MOV	PORT1,A			;e lo sparo sul port 0 della DEB 01
	        POP     ACC                     ;ripristino i suddetti registri
                POP     DPH                     
                POP     DPL                     
		POP	PSW			
		RET
;
;             Procedura di inizializzazione seriale
;
SERIAL:         PUSH	PSW			;salvo PSW
		MOV     SCON,#50H               ;seleziono modo 1, rx attivo
	     	MOV     TH1,#253                ;imposto a 253 il TH1
                ANL     PCON,#7FH               ;azzero il bit 7 del PCON (SMOD):imposto baud rate
		POP	PSW			;ripristino PSW
                RET
;
;               Procedura che consente la trasmissione di dati sulla seriale
;               
TRASMSER:	PUSH	PSW			;salvo PSW      
TRASM1: 	JBC     TI,TRASM2	 	;salta a TRASM2 se TI = 1 e azzera TI
                SJMP    TRASM1  	       	;salta a TRASM1 perche' TI = 0
                                      	  	;seriale ancora in fase di trasmissione
TRASM2:   	MOV     SBUF,TXCHAR             ;scrive nel buffer della seriale il car. da trasmettere
		POP	PSW			;ripristino PSW
                RET
;
;               Procedura per scrivere parti di testo via seriale
;
STRING:  	PUSH	PSW			;salvo registri utilizzati dalla procedura
		PUSH	ACC			
		PUSH	TXCHAR			
STRINGLOOP:     MOVX	A,@DPTR			;carica in A il contenuto della memoria puntata da DPTR
		JZ	ENDSTRING		;se l'ultimo carattere letto e' nullo (00H),salta alla fine
		MOV	TXCHAR,A		;carica il carattere nella variabile per la trasmissione
                ACALL   TRASMSER      	 	;trasmetti il carattere
                INC     DPTR            	;incrementa il puntatore al carattere
                SJMP    STRINGLOOP     		;il ciclo riparte per un altro carattere
ENDSTRING:	POP	TXCHAR			;ripristina i registri sopra indicati
		POP     ACC             
		POP	PSW			
                RET
;
;               Procedura per creare lo shift dei due led
;
SHIFT:          MOV     R0,#07
SHIFT1:         MOV     R2,#5	                ;registro usato nella procedura DELAY100
		MOV	R3,#5			;ulteriori 5 cicli di ritardo
WAITH1:         ACALL   DELAY100                ;richiamo procedure x il ritardo 
		DJNZ	R3,WAITH1
                ACALL   OUTPORT01               ;procedura che visualizza il contenuto delle variabili
                MOV     A,FPORT                 ;FPORT e SECPORT sui led della DEB01
                RL      A                       ;shift del led acceso verso sinistra del port0
                MOV     FPORT,A
                MOV	A,SECPORT
		RR	A			;shift del led acceso verso destra del port1
		MOV	SECPORT,A                 
                DJNZ    R0,SHIFT1		;fino a 7 cicli x gli otto led
                MOV     R0,#07                  ;inizializzo contatore x altri otto cicli              
SHIFT2:		MOV	R2,#5
		MOV	R3,#5                   ;ulteriori 5 cicli 
WAITH2:		ACALL	DELAY100
		DJNZ	R3,WAITH2
		ACALL	OUTPORT01		;procedura che visualizza il contenuto delle variabili
		MOV	A,FPORT
		RR	A			;shift del led acceso verso destra del port0
		MOV	FPORT,A
		MOV	A,SECPORT
		RL	A			;shift del led acceso verso sinistra del port1
		MOV	SECPORT,A
		DJNZ	R0,SHIFT2
		RET
;
;               Procedura fissa che crea un ritardo di circa 100 microsecondi variabile moltiplicando R2
;
DELAY100:       MOV 	DELAY,#75
		DJNZ 	DELAY,$
		DJNZ 	R2,DELAY100
                RET
;
;
HEADING:        DB      0CH,' Si fa scorrere la accensione di un led da destra verso sinistra',1DH,' ed uno da sinistra verso destra.',00H
                END